//created by luis gil.
//www.legil.org

PFont font;
PFont buttonfont;

float ease = 0.025;
float opacityStep = 0.05;    //determines increase in opacity each frame
float valueStep = 1.0;      //determines decrease in color value each frame
String theText = "";

boolean start = false;

Mobile[] dot = new Mobile[0];
float[] endX = new float[0];
float[] endY = new float[0];

int framenumber = 0;

void setup() {
  size(600, 300);
  smooth();
  colorMode(RGB, 255, 255, 255, 100);
  background(255);
  font = loadFont("CommercialScriptBT-Regular-96.vlw");
  buttonfont = loadFont("ArialMT-48.vlw");

}

void draw() {
  if (!start) {
  background(255);
  textFont(font);
  float tPos = width/2 + textWidth(theText)/2;
  if((millis() % 750) < 250){  
    stroke(204);
    line(tPos, height/2-48, tPos, height/2+48);
  }
  textAlign(CENTER, CENTER);
  fill(0);
  text(theText,width/2, height/2);

  if (mouseX >width/2-25 && mouseX<width/2+25
    && mouseY>height/2+80 && mouseY<height/2+100){
    noFill();
    stroke(0);
  } 
  else {
    noStroke();
    fill(0);
  }
  rect(width/2-25, height/2+80, 50, 20);
  textFont(buttonfont, 12);
  fill(175);
  text("START", width/2, height/2+90);
  }
  else {
    for (int i = 0; i < dot.length; i++) {
    dot[i].move();
  }
  framenumber += 1; //controller. after 300 frames animation will stop.
  println(framenumber);
  if (framenumber == 300) {
      fill(0, 75);
      textFont(font);
      textAlign(CENTER, CENTER);
      text(theText,width/2, height/2);
      noLoop();
    }
  }
}

void keyPressed()
{
  char k;
  k = (char)key;
  switch(k){
  case 8:
    if(theText.length()>0){
      theText = theText.substring(0, theText.length() -1);
    }
    break;
  case 13:  // Avoid special keys
  case 10:
  case 65535:
  case 127:
  case 27:
    break;
  default:
    if(textWidth(theText+k) < width){
      theText=theText+k;
    }
    break;
  }
}

void mousePressed() {
  if (mouseX >width/2-25 && mouseX<width/2+25
    && mouseY>height/2+80 && mouseY<height/2+100){

    int theCount = dotCount();
    //println(theCount);
    start = true;
  }
  noStroke();
    fill(255);
    rect(0,0,width,height);
}

int dotCount() {
  noStroke();
  fill(255);
  rect(0, height/2+79, width, 50);
  loadPixels();
  int arrayCount = 0;
  for (int u = 0; u < width; u++) {
    for (int v = 0; v < height; v++) {
      int pixelPlace = (v * width) + u;
      float bright = brightness(pixels[pixelPlace]);
      if (bright < 255/4) {
        arrayCount += 1;
        endX = append(endX, u);
        endY = append(endY, v);
      }
    }
  }

  dot = (Mobile[]) expand(dot, arrayCount);

  for (int j = 0; j < arrayCount; j++) {
    dot[j] = new Mobile(random(width), 0, endX[j], endY[j]);
  }
  return arrayCount;
}

class Mobile {
  float xOrigin, yOrigin;
  float xTarget, yTarget;
  float x = 0.0;
  float y;
  float opacity = 0.0;
  float value = 0.0;

  Mobile(float oX, float oY, float tX, float tY) {
    xOrigin = oX;
    yOrigin = oY;
    xTarget = tX;
    yTarget = tY;    
  }

  void move() {
    float newXTarget = dist(xOrigin, yOrigin, xTarget, yTarget);
    float transX = xTarget - xOrigin;
    float transY = yTarget - yOrigin;
    float maxDist = sqrt(sq(width) + sq(height));
    pushMatrix();
    translate(xOrigin, yOrigin);
    float angle = atan2(transY, transX);
    float distance = newXTarget - x;
    float amplitude = distance / 4;
    float frequency = map(distance, 0, maxDist, 0, 7 * TWO_PI);
    float y = amplitude * cos(frequency);
    rotate(angle);
    stroke(255-value, 255-value, 0, opacity);
    point(x,y);
    popMatrix();
    float addition = (newXTarget - x) * ease;
    x += addition;
    opacity += opacityStep;
    value += valueStep;
  }

}